Effectue une sélection et évalue ce qui suit.

switch value cases

value - Valeur à rechercher.

cases - Bloc de cas à rechercher. (type: block)

/default - Par défaut

case - Cas par défaut si aucun autre n’est trouvé.

Switch retourne également la valeur du bloc qu’elle exécute. Les cas peuvent être de n’importe quel type de donnée. Si aucun des autres cas ne concorde, utilisez le raffinement /DEFAULT pour spécifier un cas par défaut.

    switch 22 [
        11 [print "here"]
        22 [print "there"]
    ]
    there

    person: 'mom
    switch person [    ; words
        dad [print "here"]
        mom [print "there"]
        kid [print "everywhere"]
    ]
    there

    file: %user.r
    switch file [
        %user.r [print "here"]
        %rebol.r [print "everywhere"]
        %file.r [print "there"]
    ]
    here

    url: ftp://ftp.rebol.org
    switch url [  
        http://www.rebol.com [print "here"]
        http://www.cnet.com [print "there"]
        ftp://ftp.rebol.org [print "everywhere"]
    ]
    everywhere

    html-tag: <TITLE>
    print switch html-tag [
        <PRE>   ["Preformatted text"]
        <TITLE> ["Page title"]
        <LI>    ["Bulleted list item"]
    ]
    Page title

    time: 12:30
    switch time [
         8:00 [send wendy@domain.dom "Hey, get up"]
        12:30 [send cindy@dom.dom "Join me for lunch."]
        16:00 [send group@every.dom "Dinner anyone?"]
    ]
 

    car: pick [Ford Chevy Dodge] random 3
    print switch car [
        Ford [351 * 1.4]
        Chevy [454 * 5.3]
        Dodge [154 * 3.5]
    ]
    491.4

find - Trouve une valeur dans une série et retourne la série à cette position.

select - Trouve une valeur dans une série et retourne la valeur ou la série qui la suit.