Change une valeur dans une série et retourne la série après la modification.

change series value

series - Série au point de modification (type: series! port!)

value - La nouvelle valeur (type: any-type)

/part - Limite le changement à une longueur ou à une position donnée.

range - L’intervalle. (type: number! series! port! pair!)

/only - Change une série en tant que série.

/dup - Répète la modification le nombre de fois spécifié.

count - Le nombre de répétitions. (type: number! pair!)

Si le second argument est une valeur simple, la valeur à la position actuelle dans la première série sera remplacée. Si le second argument est une série compatible avec le premier (un type de donnée basé sur bloc ou les chaînes de caractères,) toutes ses valeurs remplaceront celles du premier argument.

Le raffinement /PART change un nombre spécifié d’éléments dans la série cible.

Pour faciliter les modifications en cascade, la fonction CHANGE retourne la série positionnée juste après la modification.

    probe head change "bog" "d"
    "dog"

    probe head change [123 "test"] "the"
    ["the" "test"]

    probe head change/dup "abc" "->" 5
    "->->->->->"

    probe head change/part "abcde" "1234" 2
    "1234cde"

    probe head change [1 4 5] [1 2 3]
    [1 2 3]

    title: copy "how it REBOL"
    change title "N"
    probe title
    "Now it REBOL"

    change find title "t" "s"
    probe title
    "Now is REBOL"

    blk: copy ["now" 12:34 "REBOL"]
    change next blk "is"
    probe blk
    ["now" "is" "REBOL"]

    probe head change/only [1 4 5] [1 2 3]
    [[1 2 3] 4 5]

    probe head change/only [1 4 5] [[1 2 3]]
    [[[1 2 3]] 4 5]

    string: copy "crush those grapes"
    change/part string "eat" find/tail string "crush"
    probe string
    "eat those grapes"

append - Ajoute une valeur à la queue d’une série et retourne la série positionnée à sa tête.

clear - Retire toutes les valeurs depuis l’index actuel jusqu’à la queue de la série. Retourne la série positionnée à sa queue.

insert - Insère une valeur dans une série et retourne la série positionnée après l’insertion.

remove - Retire une ou des valeurs d’une série et retourne la série positionnée après la modification.

sort - Trie une série.

http://www.rebol.com/docs/words/wchange.html

-Soumis par: Al.Bri_xtra.co.nz 30-Dec-2000/13:02:33-8:00:

Change est aussi pratique dans les actions des règles ‘parse. Par exemple:

    Mark: "---" MarkEnd: (
        MarkEnd: change/part Mark "&emdash;" MarkEnd
    ) :MarkEnd

modifie la chaîne d’entrée et saute par dessus le texte remplacé.